Hi everyone,
I have hundreds of assemblies made of weldment tools structural member.
I have to change the weldment profiles, and I hope these assemblies can update themself with new weldment cross sections once it is done.
Is there a method to do that?
It is not practical for me to manually click on each of the sections to update them, there are too many models and too many beams to be changed.
Currently the cross section need not change, yet I have to change the "Description" property of the weldment profile.
The model will just need to "reload" those weldment profiles. Can't even this be done?
So, there is no way to achieve this??
each structural member feature will need to have the profile re-loaded. out of the box, there is no automatic method.
if you ask in the API section, they can probably help you with a macro.
We ran into a similar situation, we also had made some changes to our Custom Weldment Profiles updating Descriptions and other custom properties. We didn't have quite as few as you seem to have but we did end up writing a small Macro to update all the profiles, so I thought that I would share the macro in case anyone else runs into the same situation.
This Macro needs to be run in a open weldment, but can easily be modified to open multiple files and update them, if you need help adding this functionality please don't hesitate to contact me.
http://www.acaciadynamics.com/Public/SolidWorks/Macro/UpdateWelmentProfile.swp
Thanks for sharing
Hello Andy,
could you share the Macro again, the link seems to be faulty. Thanks
Oops sorry, I installed some security software on my domain and it is giving me a fit so to get the file just go to http://acaciadynamics.com/Public/SolidWorks/Macro/ then right click on the Macro and Save As, it won't let me directly link to a .swp file. Let me know if you still can not get it and I will post it somewhere else.
Hello Andy,
unfortunately the download is still not working for me. If you like you could send it via email (owenb79@yahoo.com). Thanks for the help. B
It happens i'm looking for the same thing? If you right click and save link as, it says Failed - Server problem. Any chance one of you may be able to post the code in a reply?
WOW really? Solidworks wont update weldment profile changes on a rebuild? It beggars belief as to why this is the case or how this is accepted as "ok". Thankfully I dont have 100's of assemblies to update.
Here is the copy of Andy's code
' ************************************************************************************************
' Macro to reload any changes to a Structural Member Feature Profile.
' ************************************************************************************************
' BY: Andy Braham
' Acacia Dynamics
' andybraham@acaciadynamics.com
' ************************************************************************************************
' STANDARD DISCLAIMER
' ************************************************************************************************
' THIS MACRO IS DISTRIBUTED IN THE HOPE THAT IT WILL BE USEFUL, BUT WITHOUT ANY WARRANTY. IT IS
' PROVIDED "AS IS" WITHOUT WARRANTY OF ANY KIND, EITHER EXPRESSED OR IMPLIED, INCLUDING, BUT NOT
' LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE. THE
' ENTIRE RISK AS TO THE QUALITY AND PERFORMANCE OF THE PROGRAM IS WITH YOU. SHOULD THE PROGRAM
' PROVE DEFECTIVE, YOU ASSUME THE COST OF ALL NECESSARY SERVICING, REPAIR OR CORRECTION.
'
' IN NO EVENT UNLESS REQUIRED BY APPLICABLE LAW THE AUTHOR WILL BE LIABLE FOR DAMAGES, INCLUDING
' ANY GENERAL, SPECIAL, INCIDENTAL OR CONSEQUENTIAL DAMAGES ARISING OUT OF THE USE OR INABILITY
' TO USE THE MACRO, INCLUDING BUT NOT LIMITED TO LOSS OF DATA OR DATA BEING RENDERED
' INACCURATE OR LOSSES SUSTAINED.
' ************************************************************************************************
Sub UpdateProfiles()
Dim swApp As SldWorks.SldWorks
Dim swModel As SldWorks.ModelDoc2
Dim swFeat As SldWorks.Feature
Dim swCutList As SldWorks.BodyFolder
Dim swFrame As Frame
Dim swStructFeat As SldWorks.StructuralMemberFeatureData
Dim sProfilePath As String
Dim bAutoUpdate As Boolean
Set swApp = Application.SldWorks
Set swModel = swApp.ActiveDoc
Set swFeat = swModel.FirstFeature
'Set the Statusbar
Set swFrame = swApp.Frame
swFrame.SetStatusBarText "Updating Weldment Profiles"
'Find Structural Member Features
Do While Not swFeat Is Nothing
Debug.Print swFeat.GetTypeName
'Disable automatic updates for cutlist
If swFeat.GetTypeName = "SolidBodyFolder" Then
Set swCutList = swFeat.GetSpecificFeature2
'Get Automatic Update setting
bAutoUpdate = swCutList.GetAutomaticUpdate
'Disable Automatic Update of Cutlist
swCutList.SetAutomaticUpdate False
End If
'Search for Weldment Structural Members
If swFeat.GetTypeName = "WeldMemberFeat" Then
'Update Statusbar
swFrame.SetStatusBarText "Updating: " & swFeat.Name
'Update the Weldment Feature
Set swStructFeat = swFeat.GetDefinition
swStructFeat.AccessSelections swModel, Nothing
'The Profile file needs to be reassigned to trigger update
sProfilePath = swStructFeat.WeldmentProfilePath
swStructFeat.WeldmentProfilePath = sProfilePath
'If Feature is not updated send message to the user
If Not swFeat.ModifyDefinition(swStructFeat, swModel, Nothing) Then
swApp.SendMsgToUser2 "Unable to update Feature: " & swFeat.Name, swMbWarning, swMbOk
End If
End If
'Get next feature
Set swFeat = swFeat.GetNextFeature
Loop
'Update the Cutlist and return Automatic Update to its original value
swCutList.UpdateCutList
swCutList.SetAutomaticUpdate bAutoUpdate
'Set Statusbar text
swFrame.SetStatusBarText "Weldment Profile Update Complete"
'Cleanup
Set swStructFeat = Nothing
Set swFeat = Nothing
Set swModel = Nothing
Set swApp = Nothing
End Sub
I have the same issue, and tried this macro. It updates the profiles, but my weldment profiles have configurations and this replaces all the profiles with the wrong configuration. Has anyone updated this to handle weldment profiles with configurations?
I have fixed the code to allow updates to the Weldment profiles, based on design tables. The old code only worked with the separate profile files. Since 2016?, the weldment profiles are kept in one file, with configs to change the shape.
___________________________________________________________________________
Sub UpdateProfiles()
Dim swApp As SldWorks.SldWorks
Dim swModel As SldWorks.ModelDoc2
Dim swFeat As SldWorks.Feature
Dim swCutList As SldWorks.BodyFolder
Dim swFrame As Frame
Dim swStructFeat As SldWorks.StructuralMemberFeatureData
Dim sProfilePath As String
Dim bAutoUpdate As Boolean
Set swApp = Application.SldWorks
Set swModel = swApp.ActiveDoc
Set swFeat = swModel.FirstFeature
'Set the Statusbar
Set swFrame = swApp.Frame
swFrame.SetStatusBarText "Updating Weldment Profiles"
'Find Structural Member Features
Do While Not swFeat Is Nothing
Debug.Print swFeat.GetTypeName
'Disable automatic updates for cutlist
If swFeat.GetTypeName = "SolidBodyFolder" Then
Set swCutList = swFeat.GetSpecificFeature2
'Get Automatic Update setting
bAutoUpdate = swCutList.GetAutomaticUpdate
'Disable Automatic Update of Cutlist
swCutList.SetAutomaticUpdate False
End If
'Search for Weldment Structural Members
If swFeat.GetTypeName = "WeldMemberFeat" Then
'Update Statusbar
swFrame.SetStatusBarText "Updating: " & swFeat.Name
'Update the Weldment Feature
Set swStructFeat = swFeat.GetDefinition
swStructFeat.AccessSelections swModel, Nothing
'The Profile file needs to be reassigned to trigger update
'sProfilePath = swStructFeat.WeldmentProfilePath
sProfilePath = swStructFeat.ConfigurationName
' swStructFeat.WeldmentProfilePath = sProfilePath
swStructFeat.ConfigurationName = sProfilePath
'If Feature is not updated send message to the user
If Not swFeat.ModifyDefinition(swStructFeat, swModel, Nothing) Then
swApp.SendMsgToUser2 "Unable to update Feature: " & swFeat.Name, swMbWarning, swMbOk
End If
End If
'Get next feature
Set swFeat = swFeat.GetNextFeature
Loop
'Update the Cutlist and return Automatic Update to its original value
swCutList.UpdateCutList
swCutList.SetAutomaticUpdate bAutoUpdate
'Set Statusbar text
swFrame.SetStatusBarText "Weldment Profile Update Complete"
'Cleanup
Set swStructFeat = Nothing
Set swFeat = Nothing
Set swModel = Nothing
Set swApp = Nothing
End Sub
I couldn't agree more Ben! I am just starting to update weldment descriptions so the BOM will populate correctly. The model was already created and nothing updates. So my choice is to figure out how to use a macro "big thanks to those who provide them!" or click on each structural member, change to a different size, then back to the original. I really scratch my head when it comes to some things that Solidworks does. Something like this shouldn't even require a rebuild IMO. But, as mentioned, rebuild doesn't do anything anyways.
I really liked that SW doesn't update the profile on it's own. If it tries to do so, the performance would just drop down with opening/rebuilding/updating profile of every weldment model. Think of a large weldment model and it would take too long to even open the file.
I couldn't agree more.
On a simple frame not a big deal but if you designed a building with catwalks, gantries, & multi level machinery and it was all structural weldments automatic updating of the profile would make the model a bog.
(It was slow enough without any other factors as it was.)
I stand corrected..never looked at it that way. I do believe, however, there should be a rebuild option.
Just needs to have an option, you only need to turn that on when you need to change the profiles, so it wouldn't even be a problem bogging down the model in general use.
Worse than that, its possible that the previous models didn't have the cross-section aligned with the centre point, therefore even if you have to change them manually, you'll also have to select the correct profile point.
But theres always some macro out there, I juust thought I'd chime in and make the situation sound worse