AnsweredAssumed Answered

Reapply Part/Drawing templates to previously created files

Question asked by 1-PY8RX4 on Mar 9, 2010
Latest reply on Mar 11, 2010 by 1-PY8RX4

Like • Show 0 Likes0
Comment • 7

I have an issue here at work where I created parts and drawings using the standard SW templates. I didn't realize that we have setup customized templates using our drafting standards on site. The parts are fairly complex and to redraw them is not really an option. Is there any way to reapply the templates to the existing files instead of redrawing everythign?

I have tried saving the model as an IGS and re-opening it using feature recognition inside the new template. The issue I ran into is that the dimensioning standard does not follow our template. Instead of "ANSI" it lists "ISO" after feature recognition. I do not know enough about SW settings or our standards to go through and check everything so, again, it would be very helpful to have a "drag and drop" fix to this issue.

Thank you for your help in advance.

No one else has this question

Outcomes

7 Replies

Paul Marsman Mar 9, 2010 2:43 PM
Mark Correct
Correct Answer
For part document settings you can open a new file that has the settings you want and save those out to a Drafting Standard file. Then open each part you want to bring up to date and load the standard file.

For drawings you need to do those same steps but then you also need to reload the sheet format from the sheet properties window with the sheet format you want.

if you need more detail let me know.
Like • Show 0 Likes0
Actions
- 1-PY8RX4 @ Paul Marsman on Mar 10, 2010 7:49 AM
  Mark Correct
  Correct Answer
  Thanks for the reply. I wasn't sure if that would correctly use all of the settngs in our template. I am not the creator of the template and I have no idea what they have changed/added.
  
  I had to change one of the default template location options and the problem I had with dimensioning standards went away. I was able to save as an IGS, re-open, and do feature recognition inside the correct part template.
  
  As for the drawings, It would probably be easier for me to just remake them. I am not skilled in programming macros so editing your code is not an option. We have a macro already that prompts for title block info inside the part file and then automatically fills in the title block in the drawing. Should make life easier.
  
  Thanks,
  Brian
  Like • Show 0 Likes0
  Actions
  - Paul Marsman @ 1-PY8RX4 on Mar 10, 2010 8:18 AM
    Mark Correct
    Correct Answer
    you don't have to use the macro, just an option if you are going to be doing this a lot.
    
    To manually do it you just need to RMB on your drawing sheet ~ select Properties. In you sheet properties window select the sheet format you want on the left (this should be all your standard sheet formats) Then select Reload. DONE
    
    You can use this same method to change your sheet format to a different size (like if you started with A and decided B would fit better or something like that) but if you change it you don't have to select reload.... actually now that I say that you might not even have to select reload in your case because you are going from SW A to your company A and so on.
    Like • Show 0 Likes0
    Actions
Paul Marsman Mar 9, 2010 2:54 PM
Mark Correct
Correct Answer
also, here is a macro to reload the sheet format... you have to do some editing to it for your specific sheet format names and directories but it works for me quite well. I've put a button in my GUI to run this for the active drawing.

' **********************************************************************
' * PLEASE change the path/filename for the sheet templates (see below)
' **********************************************************************
' *
' * Macro changes the sheetformat (= the "paper" of your drawing) for
' * all sheets of the active drawing. You have to adjust the path and
' * the file names to the new sheet formats. After successfully changing
' * the sheetformat the drawing is saved with its current name.
' * ATTENTION: you CAN'T change the drawing template, this is not
' * possible. So with this macro you can't update document properties.
' * All sheet formats will be "userdefinied" after updating with this
' * macro. If you want to have the "standard" A-A0 formats and not
' * userdefinied you have to change the macro accordingly or use its
' * "compagnion" which reloads a standard sheettemplate
' *
' * This macro is intended to be used with PAC4SWX for batch reloading
' * of sheetformats, in case you changed you sheetformat with a new
' * company logo, new title block layout or similar. But it will also
' * word if fired from the GUI (taskplaner not tested, but should work;
' * but I would like to see you using PAC4SWX instead of taskplaner ;-))
' *
' * PAC4SWX - http://swtools.cad.de/prog_pac.htm
' *
' *
' * 17.12.2003 Stefan Berlitz
' * SolidWorks Solution Partner
' *    http://swtools.cad.de
' * Inoffizielle deutsche SolidWorks Hilfeseite
' *    http://solidworks.cad.de
' *
' **********************************************************************
Sub ReloadSheetFormat()

    Dim sheetformatpath(12) As String
    Dim sheetformatdir As String

    ' ************ EDIT path and file name HERE ************************

    ' After editing the sheetformats delete the next line or comment it
    If MsgBox(msgtext(6), vbOKOnly, "Please Edit Macro") = vbOK Then End

    ' Path to directory with sheetformats
    sheetformatdir = "M:\Sheet Formats\"

    ' path to the various sheet formats from A to A0, you may also use
    ' full pathnames, but if they are all in teh same subdir it's easier this way
    sheetformatpath(0) = sheetformatdir & "temp_a.slddrt"
    sheetformatpath(1) = sheetformatdir & "temp_av.slddrt"
    sheetformatpath(2) = sheetformatdir & "temp_b.slddrt"
    sheetformatpath(3) = sheetformatdir & "temp_c.slddrt"
    sheetformatpath(4) = sheetformatdir & "temp_d.slddrt"
    sheetformatpath(5) = sheetformatdir & "temp_e.slddrt"
    sheetformatpath(6) = sheetformatdir & "temp_a4.slddrt"
    sheetformatpath(7) = sheetformatdir & "temp_a4v.slddrt"
    sheetformatpath(8) = sheetformatdir & "temp_a3.slddrt"
    sheetformatpath(9) = sheetformatdir & "temp_a2.slddrt"
    sheetformatpath(10) = sheetformatdir & "temp_a1.slddrt"
    sheetformatpath(11) = sheetformatdir & "temp_a0.slddrt"
    ' already user defined
    sheetformatpath(12) = sheetformatdir & "blank.slddrt"

    ' ************************* EDIT END *******************************

    Dim swApp As Object
    Dim DrawingDoc As Object
    Dim Sheet As Object

    Dim Titel As String
    Dim Datei As String
    Dim temp As String
    Dim pfad As String
    Dim msgtxt As String

    Dim Name As String
    Dim paperSize As Long
    Dim templateIn As Long
    Dim scale1 As Double
    Dim scale2 As Double
    Dim firstAngle As Boolean
    Dim templateName As String
    Dim Width As Double
    Dim Height As Double
    Dim propertyViewName As String
    Dim i As Long
    Dim MySheetCount As Long
    Dim SheetNames As Variant
    Dim SheetProperties As Variant

    Const swDocDRAWING = 3
    Const swDwgTemplateCustom = 12
    Const swDwgTemplateNone = 13

    ' attach to SolidWorks
    Set swApp = CreateObject("SldWorks.Application")

    Set DrawingDoc = swApp.ActiveDoc
    If DrawingDoc Is Nothing Then
        ' check if document is open
        MsgBox "No Drawing Open"
        Exit Sub
    End If

    If (DrawingDoc.GetType <> swDocDRAWING) Then
        ' check if document is a drawing
        MsgBox "No Drawing Open"
        Exit Sub
    End If

    ' get sheet count and traverse all sheets to reload sheetfromat
    '
    MySheetCount = DrawingDoc.GetSheetCount
    SheetNames = DrawingDoc.GetSheetNames
    ' reset error messages
    msgtxt = ""

    For i = 0 To MySheetCount - 1
        ' activate next sheet
        If DrawingDoc.ActivateSheet(SheetNames(i)) Then
            ' attach to sheet object
            Set Sheet = DrawingDoc.GetCurrentSheet
            SheetProperties = Sheet.GetProperties

            ' first we have to set the sheet to use "no sheetformat", for SolidWorks
            ' wont reload a sheetformat if it is the same name as before
            Name = Sheet.GetName
            paperSize = SheetProperties(0)
            ' set NO SHEETFORMAT
            templateIn = swDwgTemplateNone
            scale1 = SheetProperties(2)
            scale2 = SheetProperties(3)
            firstAngle = CBool(SheetProperties(4))
            ' no sheetformat = no path
            templateName = ""
            ' but we need the sheet size
            Width = SheetProperties(5)
            Height = SheetProperties(6)
            propertyViewName = Sheet.CustomPropertyView

            retval = DrawingDoc.SetupSheet5( _
                        Name, _
                        paperSize, _
                        templateIn, _
                        scale1, _
                        scale2, _
                        firstAngle, _
                        templateName, _
                        Width, _
                        Height, _
                        propertyViewName, _
                        True)
            If retval = False Then
                msgtxt = "Error" & vbCrLf
            Else

                ' and now we set the new sheetformat; it is necessary to set
                ' USER DEFINIED sheetformat for SolidWorks will look for the
                ' standard templates temp_??.slddrt in your spefified folder
                ' if using the standard sheet sizes.
                templateIn = swDwgTemplateCustom

                ' get correct sheetformat for this size depending on the
                ' papersize, this will allow aleady userdefined sheetformats
                ' to properly be reloaded
                paperSize = GetSheetSizeFromPaperSize(Width, Height)
                templateName = sheetformatpath(paperSize)

                retval = DrawingDoc.SetupSheet5( _
                            Name, _
                            paperSize, _
                            templateIn, _
                            scale1, _
                            scale2, _
                            firstAngle, _
                            templateName, _
                            Width, _
                            Height, _
                            propertyViewName, _
                            True)
                If retval = False Then
                    ' ERROR : can't load new sheetformat
                    msgtxt = "Can't Load" & templateName & vbCrLf
                Else

                    ' everything worked fine, no message here for automation

                    ' save the document without backup
                    'If DrawingDoc.Save2(True) > 0 Then
                        ' error saving file
                        ' Fehler beim Speichern
                     '   msgtxt = msgtxt & msgtext(5) & vbCrLf
                    'End If

                End If

            End If
        Else
            msgtxt = "Something" & Name & vbCrLf
        End If
    Next i

    'SetDraftingStandard
    'SetCurrentLayer
    'If Len(msgtxt) Then
    '    MsgBox msgtxt
    'End If
    DrawingDoc.ViewZoomtofit2
    DrawingDoc.ForceRebuild3 False
End Sub
Function GetSheetSizeFromPaperSize(SheetWidth, SheetHeight)
    ' Function returns the SheetSize constant based on the width and heigth
    ' useful for userdefined sheetformats

    Const swDwgPaperAsize = 0
    Const swDwgPaperAsizeVertical = 1
    Const swDwgPaperBsize = 2
    Const swDwgPaperCsize = 3
    Const swDwgPaperDsize = 4
    Const swDwgPaperEsize = 5
    Const swDwgPaperA4size = 6
    Const swDwgPaperA4sizeVertical = 7
    Const swDwgPaperA3size = 8
    Const swDwgPaperA2size = 9
    Const swDwgPaperA1size = 10
    Const swDwgPaperA0size = 11
    Const swDwgPapersUserDefined = 12

    If (Round(SheetWidth, 4) = 0.2794) And (Round(SheetHeight, 4) = 0.2159) Then
        GetSheetSizeFromPaperSize = swDwgPaperAsize
    ElseIf (Round(SheetWidth, 4) = 0.2159) And (Round(SheetHeight, 4) = 0.2794) Then
        GetSheetSizeFromPaperSize = swDwgPaperAsizeVertical
    ElseIf (Round(SheetWidth, 4) = 0.4318) And (Round(SheetHeight, 4) = 0.2794) Then
        GetSheetSizeFromPaperSize = swDwgPaperBsize
    ElseIf (Round(SheetWidth, 4) = 0.5588) And (Round(SheetHeight, 4) = 0.4318) Then
        GetSheetSizeFromPaperSize = swDwgPaperCsize
    ElseIf (Round(SheetWidth, 4) = 0.8636) And (Round(SheetHeight, 4) = 0.5588) Then
        GetSheetSizeFromPaperSize = swDwgPaperDsize
    ElseIf (Round(SheetWidth, 4) = 1.1176) And (Round(SheetHeight, 4) = 0.8636) Then
        GetSheetSizeFromPaperSize = swDwgPaperEsize
    ElseIf (Round(SheetWidth, 4) = 0.297) And (Round(SheetHeight, 4) = 0.21) Then
        GetSheetSizeFromPaperSize = swDwgPaperA4size
    ElseIf (Round(SheetWidth, 4) = 0.21) And (Round(SheetHeight, 4) = 0.297) Then
        GetSheetSizeFromPaperSize = swDwgPaperA4sizeVertical
    ElseIf (Round(SheetWidth, 4) = 0.42) And (Round(SheetHeight, 4) = 0.297) Then
        GetSheetSizeFromPaperSize = swDwgPaperA3size
    ElseIf (Round(SheetWidth, 4) = 0.594) And (Round(SheetHeight, 4) = 0.42) Then
        GetSheetSizeFromPaperSize = swDwgPaperA2size
    ElseIf (Round(SheetWidth, 4) = 0.841) And (Round(SheetHeight, 4) = 0.594) Then
        GetSheetSizeFromPaperSize = swDwgPaperA1size
    ElseIf (Round(SheetWidth, 4) = 1.189) And (Round(SheetHeight, 4) = 0.841) Then
        GetSheetSizeFromPaperSize = swDwgPaperA0size
    Else
        GetSheetSizeFromPaperSize = swDwgPapersUserDefined
    End If
End Function
Like • Show 0 Likes0
Actions
Deepak Gupta Mar 10, 2010 8:49 AM
Mark Correct
Correct Answer
Check this HOW TO CHANGE/SWAP TEMPLATE/SYSTEM OPTIONS IN SOLIDWORKS
Like • Show 0 Likes0
Actions
- 1-PY8RX4 @ Deepak Gupta on Mar 10, 2010 12:31 PM
  Mark Correct
  Correct Answer
  Well, hot damn.... That is a slick little excell macro! Thank you very much, it seems to have worked perfectly on a test part I did. I will have to go through some of the options and enable/disable some of the 2008 references but it seems to be exactly what I was looking for.
  
  Thank you very much!
  Like • Show 0 Likes0
  Actions
  - 1-PY8RX4 @ 1-PY8RX4 on Mar 11, 2010 12:12 PM
    Mark Correct
    Correct Answer
    Any chance that the original developer will update this for 2010? We will be switching in a few months and it seems like it doesnt work fully with 2009 and 2010.
    
    -B
    Like • Show 0 Likes0
    Actions

Reapply Part/Drawing templates to previously created files

Outcomes

Related Content

Recommended Content