I love the shift-ctrl-q command.. but sometimes it's too much.
Like right now, I have a part with 586 configs... and I want to pull a calculated value into a design table for a subset of them... and I don't want to wait to rebuild ALL of them, and I don't want to tediously click to rebuild 75 of them. Is there a way to rebuild a selection?
I've learned a new trick today. I like the idea of a macro.. but this one seems out of my skill set. One of these days I'll find the time...
Peter Fortin wrote:
I like the idea of a macro.. but this one seems out of my skill set. One of these days I'll find the time...
Hi Peter
You definitely should have a go, the learning curve is a little steep but it's a lot of fun.
Anyway, I'm struggling to concentrate on my own projects so this seemed a nice warm up.
Select the configurations you want to rebuild and run!
I've added the option to force a rebuild or allow SW to decide what to rebuild - a bit like CTRL-Q/CTRL-B I hope.
I've tested it a little bit, but please test it for yourself before using it in anger. I would hate to cause you any problems.
macro attached / also code below
' Written in response to https://forum.solidworks.com/thread/243197
' Use at your own risk
Dim swApp As SldWorks.SldWorks
Dim swModel As SldWorks.ModelDoc2
Sub main()
Set swApp = Application.SldWorks
Set swModel = swApp.ActiveDoc
Dim configs As VBA.Collection
Set configs = GetSelectedConfigurations(swModel.SelectionManager)
If configs.Count > 0 Then
Select Case (swApp.SendMsgToUser2("Force Rebuild " & configs.Count & " configurations?", swMessageBoxIcon_e.swMbQuestion, swMessageBoxBtn_e.swMbYesNoCancel))
Case swMessageBoxResult_e.swMbHitYes
Rebuild configs, True
Case swMessageBoxResult_e.swMbHitNo
Rebuild configs, False
'Case swMessageBoxResult_e.swMbHitCancel
End Select
End If
End Sub
Private Sub Rebuild(configs As VBA.Collection, force As Boolean)
Dim currentConfigName As String
currentConfigName = swModel.ConfigurationManager.ActiveConfiguration.Name
Dim progressBar As SldWorks.UserProgressBar
swApp.GetUserProgressBar progressBar
progressBar.Start 0, configs.Count, "Rebuilding Selected Configs"
Dim swModView As SldWorks.ModelView
Set swModView = swModel.ActiveView
swModView.EnableGraphicsUpdate = False
swModel.FeatureManager.EnableFeatureTree = False
Dim i As Long
Dim config As SldWorks.Configuration
For i = 1 To configs.Count
progressBar.UpdateProgress i
Set config = configs.Item(i)
If force Then
swModel.ShowConfiguration2 config.Name
swModel.ForceRebuild3 True
Else
If config.NeedsRebuild() Then
swModel.ShowConfiguration2 config.Name
swModel.EditRebuild3
End If
End If
Next
progressBar.End
swModView.EnableGraphicsUpdate = True
swModel.FeatureManager.EnableFeatureTree = True
swModel.ShowConfiguration2 currentConfigName
End Sub
Private Function GetSelectedConfigurations(swSelMgr As SldWorks.SelectionMgr) As VBA.Collection
Set GetSelectedConfigurations = New VBA.Collection
With swSelMgr
Dim i As Long
For i = 1 To .GetSelectedObjectCount2(Mark:=-1)
If .GetSelectedObjectType3(Index:=i, Mark:=-1) = swSelCONFIGURATIONS Then
GetSelectedConfigurations.Add .GetSelectedObject6(Index:=i, Mark:=-1)
End If
Next
End With
End FunctionThank you, you didn't have to do that, but thank you very much. Seems to work great!
How about grouping your 75 configurations, that need to be rebuilt, at the top of the table, then add an empty row immediately below them. This will, in effect remove the other configurations from the design table. When you return to the model, let SW delete the other configurations. Rebuild the 75 configurations, then return to the design table and delete the empty row that you had inserted, thus re-including the configurations, below, back into the design table. When you go back to the model those configurations will be regenerated.
Hi Peter
I think you'd be best with a macro to do this. The only other way I see is to add a rebuild on save mark for the configs you want to rebuild and then save the document.
2018 SOLIDWORKS Help - Rebuild and Save Settings Dialog Box