AnsweredAssumed Answered

Applying image quality macro to all components in the assembly

Question asked by Yuri Tretyakov on Jul 20, 2020
Latest reply on Jul 20, 2020 by Austin Schukar
  • Comment • 3

Evening!

So we are all familiar with the troubled mechanism of working with the image quality (aka model detail) setting in SolidWorks and how you often need to set it manually for each part & assembly in a large model, specifically, legacy stuff created without proper templates.

Now the macros for the single file adjustment is pretty simple, as far as I understand, and it does work on a single manual run no problems:

Dim swApp As SldWorks.SldWorks
Dim instance As SldWorks.ModelDoc2
Dim QualityNum As Integer
Sub main()
Set swApp = Application.SldWorks
Set instance = swApp.ActiveDoc
QualityNum = 5
instance.SetTessellationQuality QualityNum
End Sub

I've found and tried multiple macros templates to apply this to every file in a folder or every component in assembly but none seemed to work properly. Could someone please help me out here? Also it would be great to set the wireframe quality at lowest.

 

The closest to a solution I've found here was this thread, but it didn't seem to change the components' settings.

 

Thank you in advance!

Zhen Wei Tee
Zhen Wei Tee Jul 20, 2020 7:41 AM
Correct Answer

Please see the following macro example to loop through all PART in a specific folder

You will need to change the path (highlighted in red, and dont forget to make sure it is end with \)

 

 

'==================== Preamble ===================='
Option Explicit
Dim swApp As SldWorks.SldWorks
Dim swModel As SldWorks.ModelDoc2
Dim sFileName As String
Dim Path As String
Dim nErrors As Long
Dim nWarnings As Long
Dim QualityNum As Integer

'=================================================='

'==================== MainCode ===================='
Sub main()

Set swApp = Application.SldWorks

'Get active document
Set swModel = swApp.ActiveDoc

Path = "C:\Users\zhen-wei.tee\Desktop\Sandbox\SolidworkForum\242934\Launcher Assy\" 'Remember to end with \

sFileName = Dir(Path & "*.sldprt")

Do Until sFileName = ""
Set swModel = swApp.OpenDoc6(Path + sFileName, swDocPART, swOpenDocOptions_Silent, "", nErrors, nWarnings)
Set swModel = swApp.ActiveDoc

'adjsut image quality
QualityNum = 5
swModel.SetTessellationQuality QualityNum

'save
swModel.Save 'Should use save3 for proper control

swApp.CloseDoc swModel.GetTitle
Set swModel = Nothing
sFileName = Dir
Loop

Set swModel = Nothing

End Sub

'=================================================='

 

[Edit]

The macro will/should open and save all part, but not the asm, to make it work for all asm you might want to add the following do...loop after the first loop

sFileName = Dir(Path & "*.sldasm")

Do Until sFileName = ""
Set swModel = swApp.OpenDoc6(Path + sFileName, swDocASSEMBLY, swOpenDocOptions_Silent, "", nErrors, nWarnings)
Set swModel = swApp.ActiveDoc

'adjsut image quality
QualityNum = 5
swModel.SetTessellationQuality QualityNum

'save
swModel.Save 'Should use save3 for proper control

swApp.CloseDoc swModel.GetTitle
Set swModel = Nothing
sFileName = Dir
Loop

See the reply in context
No one else had this question

Outcomes