I saw long time ago swp file for part creation i.e. plate with holes.
After start of macro, I've been asked for all dimensions and quantity of holes stem by step.
I saw that file on some of forum with parts for engineers, but I don't remember which forum was that.
The easier option would be to use a template part and modify its parameters, rather than building features from scratch as your would rely on too many APIs. So it would be something similar to how Design Table works, but you can modify parameters in your own way.
Although the following example is not a VBA macro, but it can help you to get an idea of what I'm suggesting: Script generates model from input parameters using SOLIDWORKS API
No, I'm looking exactly for that solution.
I'm starting swp file, solidworks step by step is asking me for each dimention and parameter (quantity of holes and so on).
Guys, I found swb file, which automatically makes part.
But not asking for any dimensions.
How to modify code for that?
Here is swb file:
1. Find the dimension you want to modify
2. Replace it with "myDim"
3. in the line above, insert :
Dim myDim as Double
myDim = InputBox("Enter a value in meter")
or : myDim = InputBox("Enter a value in millimeter") / 1000
For example, to change the interior diameter of the hole on the left:
Sub codeBag3(part, wMat)
Dim myDim As Double
myDim = InputBox("Enter a radius in millimeter for the hole") / 1000
cLn part, wMat, 0, 0, 0, 0.004864
cLn part, wMat, 0, 0.004864, 0.000581, myDim
cLn part, wMat, 0.000581, myDim, 0.0093, myDim
cLn part, wMat, 0.0093, myDim, 0.0093, 0
cLn part, wMat, 0.0093, 0, 0, 0
cCLn part, wMat, 0.0093, 0, 0, 0
part.SketchManager.InsertSketch True
End Sub
Although in my opinion, trying to understand the structure of this swb file and modifying it to fit your needs, is going to be a headache.
For a more easy way, try : 2017 SOLIDWORKS API Help - Create Extrusion Feature Example
and add some InputBox there.
D'oh...
I tried to made simple flange, 3 dimensions, external diameter, internal diameter and thickness.
And it's not working, strange things are happening :-(
I am asked doble 2x for the same dimension, but not asked for thickness ;-(
Could you take a look at the code?
Try this:
Option Explicit
Dim swApp As SldWorks.SldWorks
Dim swModel As SldWorks.ModelDoc2
Dim swFeat As SldWorks.Feature
Dim swDisplayDim As SldWorks.DisplayDimension
Dim myDim As Double
Dim skSegment As SldWorks.SketchSegment
Dim myModelView As SldWorks.ModelView
Dim boolstatus As Boolean
Dim swSheetWidth As Double
Dim swSheetHeight As Double
Sub main()
swSheetWidth = 0
swSheetHeight = 0
Set swApp = Application.SldWorks
'Set swModel = swApp.NewDocument("C:\ProgramData\SOLIDWORKS\SOLIDWORKS 2020\templates\Part.prtdot", 0, swSheetWidth, swSheetHeight)
Set swModel = swApp.NewDocument("V:\Engineering\7-Standards\CADowskie_szablony\SZABLONY_SOLIDWORKS\STOKOTA_Part_V3.prtdot", 0, swSheetWidth, swSheetHeight)
swApp.SetUserPreferenceToggle swUserPreferenceToggle_e.swInputDimValOnCreate, False
Set myModelView = swModel.ActiveView
myModelView.FrameState = swWindowState_e.swWindowMaximized
SelectPlane 1
swModel.SketchManager.InsertSketch True
swModel.SketchManager.AddToDB = True
myDim = InputBox("Enter a external diamteter in millimeter") / 1000
Set skSegment = swModel.SketchManager.CreateCircle(0#, 0#, 0#, myDim / 2, 0, 0#)
skSegment.Select4 False, Nothing
Set swDisplayDim = swModel.AddDimension2(0.1, 0.1, 0)
myDim = InputBox("Enter a internal diamteter in millimeter") / 1000
Set skSegment = swModel.SketchManager.CreateCircle(0#, 0#, 0#, myDim / 2, 0, 0#)
skSegment.Select4 False, Nothing
Set swDisplayDim = swModel.AddDimension2(0.1, 0.05, 0)
swModel.SketchManager.AddToDB = False
swModel.SketchManager.InsertSketch True
myDim = InputBox("Enter thickness in millimeter") / 1000
Set swFeat = swModel.FeatureManager.FeatureExtrusion2(True, False, False, swEndConditions_e.swEndCondBlind, swEndConditions_e.swEndCondBlind, myDim, 0, False, False, False, False, 0, 0, False, False, False, False, True, True, True, swStartConditions_e.swStartSketchPlane, 0, False)
swModel.SelectionManager.EnableContourSelection = False
swApp.SetUserPreferenceToggle swUserPreferenceToggle_e.swInputDimValOnCreate, True
swModel.ClearSelection2 True
boolstatus = swModel.EditRebuild3()
swModel.ViewZoomtofit2
End Sub
Sub SelectPlane(PlaneIndex As Integer)
Dim i As Integer
Set swFeat = swModel.FirstFeature
While Not swFeat Is Nothing
If swFeat.GetTypeName = "RefPlane" Then
i = i + 1
If i = PlaneIndex Then
swFeat.Select2 False, 0
Exit Sub
End If
End If
Set swFeat = swFeat.GetNextFeature
Wend
End Sub
Wow, great.
I tried to go further (some undercut and patterned holes around the flange).
For now I'm trying to make undercut (marked by green on the picture).
My code for that is:
myDim = InputBox("Enter a cut diameteter in millimeter") / 1000
Set skSegment = swModel.SketchManager.CreateCircle(0#, 0#, 0#, myDim / 2, 0, 0#)
skSegment.Select4 False, Nothing
Set swDisplayDim = swModel.AddDimension2(0.1, 0.1, 0)
myDim = InputBox("Enter depth in millimeter") / 1000
Set swFeat = swModel.FeatureManager.FeatureCut2(True, False, False, swEndConditions_e.swEndCondBlind, swEndConditions_e.swEndCondBlind, myDim, 0, False, False, False, False, 0, 0, False, False, False, False, True, True, True, swStartConditions_e.swStartSketchPlane, 0, False)
swModel.SelectionManager.EnableContourSelection = False
But then I am asked for diameter twice - once for "Enter a cut diameteter in millimeter" and then once again (standard dimension demand). Then I am asked for depth and... nothing happend, solidworks stays on sketch.
Finally I want to made part as on the picture.
To exit the sketch you need to use:
swModel.SketchManager.InsertSketch True
Damn, I'm trying and now macro is exiting the sketch and that's all, no cut.
And still I'm asked twice for cut diameter ;-(
Post all your code
Option Explicit
Dim swApp As SldWorks.SldWorks
Dim swModel As SldWorks.ModelDoc2
Dim swFeat As SldWorks.Feature
Dim swDisplayDim As SldWorks.DisplayDimension
Dim myDim As Double
Dim skSegment As SldWorks.SketchSegment
Dim myModelView As SldWorks.ModelView
Dim boolstatus As Boolean
Dim swSheetWidth As Double
Dim swSheetHeight As Double
Sub main()
swSheetWidth = 0
swSheetHeight = 0
Set swApp = Application.SldWorks
'Set swModel = swApp.NewDocument("C:\ProgramData\SOLIDWORKS\SOLIDWORKS 2020\templates\Part.prtdot", 0, swSheetWidth, swSheetHeight)
Set swModel = swApp.NewDocument("V:\Engineering\7-Standards\CADowskie_szablony\SZABLONY_SOLIDWORKS\STOKOTA_Part_V3.prtdot", 0, swSheetWidth, swSheetHeight)
swApp.SetUserPreferenceToggle swUserPreferenceToggle_e.swInputDimValOnCreate, False
Set myModelView = swModel.ActiveView
myModelView.FrameState = swWindowState_e.swWindowMaximized
SelectPlane 1
swModel.SketchManager.InsertSketch True
swModel.SketchManager.AddToDB = True
myDim = InputBox("Enter a external diamteter in millimeter") / 1000
Set skSegment = swModel.SketchManager.CreateCircle(0#, 0#, 0#, myDim / 2, 0, 0#)
skSegment.Select4 False, Nothing
Set swDisplayDim = swModel.AddDimension2(0.1, 0.1, 0)
myDim = InputBox("Enter a internal diamteter in millimeter") / 1000
Set skSegment = swModel.SketchManager.CreateCircle(0#, 0#, 0#, myDim / 2, 0, 0#)
skSegment.Select4 False, Nothing
Set swDisplayDim = swModel.AddDimension2(0.1, 0.05, 0)
swModel.SketchManager.AddToDB = False
swModel.SketchManager.InsertSketch True
myDim = InputBox("Enter thickness in millimeter") / 1000
Set swFeat = swModel.FeatureManager.FeatureExtrusion2(True, False, False, swEndConditions_e.swEndCondBlind, swEndConditions_e.swEndCondBlind, myDim, 0, False, False, False, False, 0, 0, False, False, False, False, True, True, True, swStartConditions_e.swStartSketchPlane, 0, False)
swModel.SelectionManager.EnableContourSelection = False
swApp.SetUserPreferenceToggle swUserPreferenceToggle_e.swInputDimValOnCreate, True
swModel.ClearSelection2 True
boolstatus = swModel.EditRebuild3()
swModel.ViewZoomtofit2
SelectPlane 1
'swModel.SketchManager.InsertSketch True
swModel.SketchManager.AddToDB = True
myDim = InputBox("Enter a cut diameteter in millimeter") / 1000
Set skSegment = swModel.SketchManager.CreateCircle(0#, 0#, 0#, myDim / 2, 0, 0#)
skSegment.Select4 False, Nothing
Set swDisplayDim = swModel.AddDimension2(0.1, 0.1, 0)
myDim = InputBox("Enter depth in millimeter") / 1000
swModel.SketchManager.InsertSketch True
Set swFeat = swModel.FeatureManager.FeatureCut2(True, False, True, swEndConditions_e.swEndCondBlind, swEndConditions_e.swEndCondBlind, myDim, 0, False, False, False, False, 0, 0, False, False, False, False, True, True, True, swStartConditions_e.swStartSketchPlane, 0, False)
swModel.SelectionManager.EnableContourSelection = False
End Sub
Sub SelectPlane(PlaneIndex As Integer)
Dim i As Integer
Set swFeat = swModel.FirstFeature
While Not swFeat Is Nothing
If swFeat.GetTypeName = "RefPlane" Then
i = i + 1
If i = PlaneIndex Then
swFeat.Select2 False, 0
Exit Sub
End If
End If
Set swFeat = swFeat.GetNextFeature
Wend
End Sub
That should do it
Dim swApp As SldWorks.SldWorks
Dim swModel As SldWorks.ModelDoc2
Dim swDisplayDim As SldWorks.DisplayDimension
Dim myDim As Double
Dim myDim2 As Double
Dim skSegment As SldWorks.SketchSegment
Dim myModelView As SldWorks.ModelView
Dim boolstatus As Boolean
Dim swSheetWidth As Double
Dim swSheetHeight As DoubleSub main()
Dim swFeat As SldWorks.Feature
swSheetWidth = 0
swSheetHeight = 0
Set swApp = Application.SldWorks
'Set swModel = swApp.NewDocument("C:\ProgramData\SOLIDWORKS\SOLIDWORKS 2020\templates\Part.prtdot", 0, swSheetWidth, swSheetHeight)
Set swModel = swApp.NewDocument("V:\Engineering\7-Standards\CADowskie_szablony\SZABLONY_SOLIDWORKS\STOKOTA_Part_V3.prtdot", 0, swSheetWidth, swSheetHeight)
swApp.SetUserPreferenceToggle swUserPreferenceToggle_e.swInputDimValOnCreate, False
Set myModelView = swModel.ActiveView
myModelView.FrameState = swWindowState_e.swWindowMaximized
'create sketch
swModel.ClearSelection2 True
SelectPlane 1
swModel.SketchManager.InsertSketch True
swModel.SketchManager.AddToDB = TruemyDim = InputBox("Enter a external diameter in millimeter", "", 200) / 1000
Set skSegment = swModel.SketchManager.CreateCircle(0#, 0#, 0#, myDim / 2, 0, 0#)
skSegment.Select4 False, Nothing
Set swDisplayDim = swModel.AddDimension2(0.1, 0.1, 0)myDim = InputBox("Enter a internal diameter in millimeter", "", 50) / 1000
Set skSegment = swModel.SketchManager.CreateCircle(0#, 0#, 0#, myDim / 2, 0, 0#)
skSegment.Select4 False, Nothing
Set swDisplayDim = swModel.AddDimension2(0.1, 0.05, 0)'close sketch
swModel.SketchManager.AddToDB = False
swModel.SketchManager.InsertSketch True'create feature
myDim = InputBox("Enter thickness in millimeter", "", 10) / 1000
Set swFeat = swModel.FeatureManager.FeatureExtrusion2(True, False, False, swEndConditions_e.swEndCondBlind, swEndConditions_e.swEndCondBlind, myDim, 0, False, False, False, False, 0, 0, False, False, False, False, True, True, True, swStartConditions_e.swStartSketchPlane, 0, False)
'create sketch
swModel.ClearSelection2 True
SelectPlane 1
swModel.SketchManager.InsertSketch True
swModel.SketchManager.AddToDB = TruemyDim = InputBox("Enter a cut diameter in millimeter", "", 60) / 1000
Set skSegment = swModel.SketchManager.CreateCircle(0#, 0#, 0#, myDim / 2, 0, 0#)
skSegment.Select4 False, Nothing
Set swDisplayDim = swModel.AddDimension2(0.1, 0.1, 0)'close sketch
swModel.SketchManager.AddToDB = False
swModel.SketchManager.InsertSketch True'create feature
myDim = InputBox("Enter depth in millimeter", "", 5) / 1000
Set swFeat = swModel.FeatureManager.FeatureCut2(True, False, True, swEndConditions_e.swEndCondBlind, swEndConditions_e.swEndCondBlind, myDim, 0, False, False, False, False, 0, 0, False, False, False, False, False, True, True, True, True, True)
'create sketch
swModel.ClearSelection2 True
SelectPlane 1
swModel.SketchManager.InsertSketch True
swModel.SketchManager.AddToDB = TruemyDim2 = InputBox("Enter an entraxe diameter in millimeter", "", 160) / 1000
myDim = InputBox("Enter a hole diameter in millimeter", "", 10) / 1000
Set skSegment = swModel.SketchManager.CreateCircle(0#, myDim2 / 2, 0#, myDim / 2, myDim2 / 2, 0#)
skSegment.Select4 False, Nothing
Set swDisplayDim = swModel.AddDimension2(0.1, 0.1, 0)'close sketch
swModel.SketchManager.AddToDB = False
swModel.SketchManager.InsertSketch True'create feature
Set swFeat = swModel.FeatureManager.FeatureCut2(True, False, True, swEndConditions_e.swEndCondThroughAll, swEndConditions_e.swEndCondThroughAll, 0, 0, False, False, False, False, 0, 0, False, False, False, False, False, True, True, True, True, True)
'create axis
swModel.ClearSelection2 True
SelectPlane 2
SelectPlane 3
swModel.InsertAxis2 True
Dim swAxisFeat As SldWorks.Feature
Set swAxisFeat = swModel.Extension.GetLastFeatureAdded'create feature
swAxisFeat.Select2 False, 1
swFeat.Select2 True, 4
myDim = InputBox("Enter number of holes", "", 8)
Set swFeat = swModel.FeatureManager.FeatureCircularPattern4(myDim, 2 * 3.14159265359, False, "", False, True, False)
'end
swApp.SetUserPreferenceToggle swUserPreferenceToggle_e.swInputDimValOnCreate, True
swModel.ClearSelection2 True
swModel.ForceRebuild3 False
swModel.ViewZoomtofit2
End Sub
Sub SelectPlane(PlaneIndex As Integer)
Dim swFeat As SldWorks.Feature
Dim i As Integer
Set swFeat = swModel.FirstFeature
While Not swFeat Is Nothing
If swFeat.GetTypeName = "RefPlane" Then
i = i + 1
If i = PlaneIndex Then
swFeat.Select2 True, 0
Exit Sub
End If
End If
Set swFeat = swFeat.GetNextFeature
Wend
End Sub
Fifi Riri, wow, wow, and once again wow. Thank you, apreciated.
1. Find the dimension you want to modify
2. Replace it with "myDim"
3. in the line above, insert :
For example, to change the interior diameter of the hole on the left:
Although in my opinion, trying to understand the structure of this swb file and modifying it to fit your needs, is going to be a headache.
For a more easy way, try : 2017 SOLIDWORKS API Help - Create Extrusion Feature Example
and add some InputBox there.