AnsweredAssumed Answered

Drawing Font Updates

Question asked by Ian Chamberlin on Aug 2, 2019
Latest reply on Aug 15, 2019 by Ian Chamberlin

Like • Show 0 Likes0
Comment • 9

Greetings all. I'm trying to update drawing font family, size, etc... via a macro and need a little help getting the VBA code sorted out.

The scenario here is that we updated our drawing templates recently and are using different fonts for notes, dimensions, etc... than we did on the older template. When we process a change to these drawings we are updating to the new template but the fonts are not updating on the drawing to the newer type.

For example, when I open up an old drawing it uses Century Gothic for both the Annotations and Dimensions font option under the Document Properties tab. When I switch the drawing template to the new version the fonts are not updated to Arial which we are using in the new template. If I create a drawing from scratch using the new format everything is in Arial as expected so I know the new template has the right settings.

It seems like the template remembers the old font settings from the format and just reuses them. Since I can't figure out a way to force it to reread the format to get the new fonts I think I'm stuck with updating them all via macro code. I also need to make sure that all notes, dimensions, etc... are set to use the default font otherwise they won't update properly even when I change the default font. So I think I need a two part macro: step one needs to select all dimensions, notes, etc... and set them to use the default font; step two needs to change the default font for the drawing.

I have code that is partially working for the step two. I can set the font family but not the height, bolding, etc... My code for that portion is as follows:

Option Explicit

Dim swApp As SldWorks.SldWorks
Dim swModel As SldWorks.ModelDoc2
Dim swDraw As SldWorks.DrawingDoc

Dim FontName As String
Dim retval As Boolean

Dim TextFormatObj As Object
Dim swTextFormat As SldWorks.TextFormat

Sub main()

Set swApp = Application.SldWorks
Set swModel = swApp.ActiveDoc
Set swDraw = swModel

FontName = "Arial"

retval = ReplaceFont(swDetailingAnnotationTextFormat, FontName)
retval = ReplaceFont(swDetailingBalloonTextFormat, FontName)
retval = ReplaceFont(swDetailingBillOfMaterialTextFormat, FontName)
retval = ReplaceFont(swDetailingDatumTextFormat, FontName)
retval = ReplaceFont(swDetailingDetailLabelTextFormat, FontName)
retval = ReplaceFont(swDetailingDetailTextFormat, FontName)
retval = ReplaceFont(swDetailingDimensionTextFormat, FontName)
retval = ReplaceFont(swDetailingGeneralTableTextFormat, FontName)
retval = ReplaceFont(swDetailingGeometricToleranceTextFormat, FontName)
retval = ReplaceFont(swDetailingHoleTableTextFormat, FontName)
retval = ReplaceFont(swDetailingNoteTextFormat, FontName)
retval = ReplaceFont(swDetailingRevisionTableTextFormat, FontName)
retval = ReplaceFont(swDetailingSectionLabelTextFormat, FontName)
retval = ReplaceFont(swDetailingSectionTextFormat, FontName)
retval = ReplaceFont(swDetailingSurfaceFinishTextFormat, FontName)
retval = ReplaceFont(swDetailingTableTextFormat, FontName)
retval = ReplaceFont(swDetailingViewArrowTextFormat, FontName)
retval = ReplaceFont(swDetailingViewTextFormat, FontName)
retval = ReplaceFont(swDetailingWeldSymbolTextFormat, FontName)

End Sub

Function ReplaceFont(AName As swUserPreferenceTextFormat_e, Fname As String)
Set TextFormatObj = swModel.GetUserPreferenceTextFormat(AName)
Set swTextFormat = TextFormatObj
swTextFormat.TypeFaceName = Fname
ReplaceFont = swModel.SetUserPreferenceTextFormat(AName, swTextFormat)
End Function

I can't seem to find any code for step one that will allow me to set all dimensions, notes, etc... to use the default font.

Any help would be greatly appreciated.

No one else has this question

Outcomes

Josh Brady Aug 2, 2019 5:37 PM

OK... First, you need to be sure of the difference between a template and a sheet format.

It really sounds to me like you are changing the sheet format (the title block, all the default notes, etc), but you are NOT changing the template. The sheet format does NOT contain any font information (size, family, etc) for the document. The document font can only be accessed through Tools->Options, Document Properties tab. When you replace your template, does the font update under Tools->Options, Document Properties tab? If not, you are not replacing your template. You're replacing your sheet format. You can't really replace a template.

So... Once you "replace your template"... Does every note/dimension/etc. have the "Use Document" checkbox cleared in its font properties? If not, you don't need to select everything etc etc. You just need to use a macro to update the document font. Or you can manually update it in the Document PRoperties tab.

Your macro already changes the document font family... and it sounds like it already works to do that, right? You have 99.5% of what you need.

Right under swTextFormat.TypeFaceName = Fname, you just need a line that says swTextFormat.CharHeight = [whatever height you want - units are meters].

Actions

Ian Chamberlin @ Josh Brady on Aug 7, 2019 9:52 AM

I believe I am only changing the sheet format. When I do the replace operation, the fonts used for Annotations and Dimensions do not change. I think this is why I need to be able both change the default font used in the drawing and make all notes/dimensions use the default font. The macro I have takes care of the default font changes (and now I can set the height thanks to your note on that) but I still need some code to select all (or cycle through one by one) of the dimensions and notes to force them to use the default font. There is no consistency in whether or not the default font checkbox was checked for dimensions and notes. Some have it and some do not. Replacing the sheet format does not change the status of the use default checkbox.

So for the font change to "take" I need to ensure every dimension and note is set to use the default font. This is where I need macro code help.

Hope this response is clear and thanks for the help.

Actions

Josh Brady @ Ian Chamberlin on Aug 7, 2019 10:23 AM

Ian Chamberlin wrote:

There is no consistency in whether or not the default font checkbox was checked for dimensions and notes. Some have it and some do not. Replacing the sheet format does not change the status of the use default checkbox.

Just to make sure I'm understanding right... It should be pretty unusual to have annotations/dimensions that don't use the document font. Are you saying that you have a bunch of existing files where (all/most/some/few) do not use document font? Like, the box is un-checked even before you try to replace the template or change the document font? If you have users creating docs like this, that should be addressed as well.

This should get you pretty close. Written, not tested....

Dim swApp As SldWorks.SldWorks
Dim swDwg As SldWorks.DrawingDoc
Dim swAnn As SldWorks.Annotation

Sub main()

Set swApp = Application.SldWorks
If swApp.ActiveDoc.GetType <> swDocDRAWING Then
MsgBox "This works on drawings only."
Exit Sub
End If

Set swDwg = swApp.ActiveDoc

Dim vViews As Variant
Dim vAnnots As Variant
Dim theView As SldWorks.View
Dim vShtViews As Variant

Dim i As Long
Dim j As Long
Dim k As Long
Dim l As Long
vViews = swDwg.GetViews
'This is an array of arrays. Each member of the outer array is an array of the views on one sheet.
For i = 0 To UBound(vViews)
vShtViews = vViews(i)
For j = 0 To UBound(vShtViews)
Set theView = vShtViews(j)
vAnnots = theView.GetAnnotations
For k = 0 To UBound(vAnnots)
Set swAnn = vAnnots(k)
For l = 0 To swAnn.GetTextFormatCount - 1
If False = swAnn.GetUseDocTextFormat(l) Then
swAnn.SetTextFormat l, True, Nothing
End If
Next k
Next k
Next j
Next i
End Sub

Actions

Ian Chamberlin @ Josh Brady on Aug 8, 2019 1:04 PM

Agreed, it should be unusual but we haven't been good about enforcing standards in the past so a lot of older drawings have cases where the font was changed to make it fit the drawing better. Not something we do now but something we have to deal with due to past bad habits. And yes, the box is unchecked both before and after trying to update the template.

When I tried to run your code, I got an error at the "Next k" line:

Compile error: Invalid Next control variable reference

Thoughts?

Actions

Josh Brady @ Ian Chamberlin on Aug 8, 2019 1:41 PM

Agreed, it should be unusual but we haven't been good about enforcing standards in the past so a lot of older drawings have cases where the font was changed to make it fit the drawing better.

Dang. That kind of incompetence just burns me up. Not only doing things the wrong way, but doing it the harder way out of ignorance of the right way.

Sorry about the error... There are two "Next k" lines. The first one should be "Next l" (that's lower case L)

Actions

Glenn Schroeder @ Ian Chamberlin on Aug 9, 2019 8:20 AM

Ian Chamberlin wrote:

I believe I am only changing the sheet format. When I do the replace operation, the fonts used for Annotations and Dimensions do not change. I think this is why I need to be able both change the default font used in the drawing and make all notes/dimensions use the default font. The macro I have takes care of the default font changes (and now I can set the height thanks to your note on that) but I still need some code to select all (or cycle through one by one) of the dimensions and notes to force them to use the default font. There is no consistency in whether or not the default font checkbox was checked for dimensions and notes. Some have it and some do not. Replacing the sheet format does not change the status of the use default checkbox.

So for the font change to "take" I need to ensure every dimension and note is set to use the default font. This is where I need macro code help.

Hope this response is clear and thanks for the help.

I don't usually look at posts in the API section of the forum, but for some reason I opened this one. Dimensions aren't in the sheet format, so the highlighted statement above is incorrect. What's the difference between a sheet format and drawing template? might be helpful.

That's all I got. It looks like Josh has fixed your issue with his macro to go through and check the boxes for "Use document font".

Actions

John Stoltzfus Aug 9, 2019 6:24 AM

Ian Chamberlin

Once you make your changes in the Template and the Sheet Format, do yourself a favor and save your "Drafting Standards" in the Drawing Document Properties..

Actions

Ian Chamberlin Aug 13, 2019 3:07 PM

Well things are kind of working now. Thanks to Josh's code I now have two working macros. The first one changes all of the default fonts in the document properties and the second (from Josh) forces everything to use the default font. So dimensions and notes on the drawing are good now.

Two issues remain: the revision history table isn't updating without manual intervention and the title block fonts are being changed as well which I don't want.

The revision table is set to use the default font on all the drawings which is correct but for some reason when the default font is changed the table does not update. The only way I have found to get it to update properly is to select the entire table and then unclick and reclick the Use Document Font button. This works but is a manual process and thus prone to being forgotten. Is this a known bug? Is there some other way around this via automation or another macro procedure/call?

As for the title block fonts, is there some way to exclude them from being selected when the macro runs? I don't see anything in the code that is specifically for them but I'm no guru so maybe I'm just missing it. They need to stay at their original fonts and sizes to meet our standards.

Thanks for the help so far and hopefully someone can help with these last two items.

Actions

Ian Chamberlin @ Ian Chamberlin on Aug 15, 2019 5:06 PM

I have combined the two macros into one code base so the default font is changed and the annotations are selected view by view now which fixes the title block font issue. The revision table font is still an outstanding item but I might be able to cycle through that row by row in code vs. manually pushing the button for the entire table.

Current code is below in case anybody is interested:

Option Explicit

Dim swApp As SldWorks.SldWorks
Dim swModel As SldWorks.ModelDoc2
Dim swDraw As SldWorks.DrawingDoc
Dim swView As SldWorks.View
Dim swTextFormat As SldWorks.TextFormat
Dim TextFormatObj As Object

Dim FontName As String
Dim retval As Boolean

Dim i As Long
Dim j As Long
Dim annotations As Variant
Dim notes As SldWorks.Annotation
Dim count As Long
Dim bool As Boolean

Sub main()

Set swApp = Application.SldWorks
Set swModel = swApp.ActiveDoc
Set swDraw = swModel

' Change the default font family and size for drawing annotations, dimensions, etc...

FontName = "Arial"

retval = ReplaceFont(swDetailingAnnotationTextFormat, FontName)
retval = ReplaceFont(swDetailingBalloonTextFormat, FontName)
retval = ReplaceFont(swDetailingBillOfMaterialTextFormat, FontName)
retval = ReplaceFont(swDetailingDatumTextFormat, FontName)
retval = ReplaceFont(swDetailingDetailLabelTextFormat, FontName)
retval = ReplaceFont(swDetailingDetailTextFormat, FontName)
retval = ReplaceFont(swDetailingDimensionTextFormat, FontName)
retval = ReplaceFont(swDetailingGeneralTableTextFormat, FontName)
retval = ReplaceFont(swDetailingGeometricToleranceTextFormat, FontName)
retval = ReplaceFont(swDetailingHoleTableTextFormat, FontName)
retval = ReplaceFont(swDetailingNoteTextFormat, FontName)
retval = ReplaceFont(swDetailingRevisionTableTextFormat, FontName)
retval = ReplaceFont(swDetailingSectionLabelTextFormat, FontName)
retval = ReplaceFont(swDetailingSectionTextFormat, FontName)
retval = ReplaceFont(swDetailingSurfaceFinishTextFormat, FontName)
retval = ReplaceFont(swDetailingTableTextFormat, FontName)
retval = ReplaceFont(swDetailingViewArrowTextFormat, FontName)
retval = ReplaceFont(swDetailingViewTextFormat, FontName)
retval = ReplaceFont(swDetailingWeldSymbolTextFormat, FontName)

' Force all annotations, dimensions, etc... to use the default font

' Iterate through all the views on the drawing to find annotations  
Set swView = swDraw.GetFirstView  
Do While Not swView Is Nothing  
Debug.Print swView.Name  
count = swView.GetAnnotationCount  

' Iterate through all the annotations in each drawing view that has them and set to use document font  
If count > 0 Then  
        annotations = swView.GetAnnotations  
        For j = 0 To UBound(annotations)  
            Set notes = annotations(j)  
            If notes.OwnerType <> swAnnotationOwner_DrawingTemplate Then  
                bool = notes.SetTextFormat(i, True, swTextFormat)  
            End If  
        Next j  
    End If  
    Set swView = swView.GetNextView  
Loop  

End Sub

Function ReplaceFont(AName As swUserPreferenceTextFormat_e, Fname As String)
Set TextFormatObj = swModel.GetUserPreferenceTextFormat(AName)
Set swTextFormat = TextFormatObj
swTextFormat.TypeFaceName = Fname
swTextFormat.CharHeight = 0.003
ReplaceFont = swModel.SetUserPreferenceTextFormat(AName, swTextFormat)
End Function

Actions

Drawing Font Updates

Outcomes

Related Content

Recommended Content