AnsweredAssumed Answered

Adding Horizontal and Vertical Dimensions Simultaneously

Question asked by Adam Nunn on Feb 6, 2019
Latest reply on May 2, 2019 by Dave Laban
  • Comment • 35

I often find I am making both horizontal and vertical dimensions between to points, usually for hole centers. is there a way to do this at once instead of having to click:

 

Dim tool

point A

Point B

place  horz. dim

confirm

 

Dim tool

point A

Point B

place vert. dim

confirm

 

I would like to do:

 

Dim tool

point A

Point B

place  horz. dim

place vert. dim

confirm

 

Is this possible?

Rob Edwards
Rob Edwards Feb 6, 2019 5:34 PM
Correct Answer

Dwight Livingston wrote:

 

One approach:

 

1. Put the horizontal dimension on top.

2. If top point is left of bottom point, put vertical dim to left of top point.

3. If top point is right of bottom point, put vertical dim to right of top point

Thanks Dwight

 

worked a charm I think?

I made a bitmap for the button but it looks a bit funny.  Looked ok till it went on toolbar?

 

 

 

' VandHSketchDims1.1
' SW2016
' Adds Horizontal and Vertical Dimensions to two sketch points in an active sketch
' If somethings not right this macro just exits.
' you must be in an active sketch and have exactly 2 sketch points selected
' it positions the dims centrally to the top and trys to choose the best side
' inspired by https://forum.solidworks.com/thread/228935
' by 369 6feb19

Option Explicit

Dim SketchPoints(1) As SldWorks.SketchPoint

Sub main()

    Dim swmodel As SldWorks.ModelDoc2: Set swmodel = Application.SldWorks.ActiveDoc
   
    If swmodel Is Nothing Then Exit Sub
   
    Dim swSelMgr As SldWorks.SelectionMgr: Set swSelMgr = swmodel.SelectionManager
   
    If swSelMgr.GetSelectedObjectCount <> 2 Then Exit Sub
   
    If swSelMgr.GetSelectedObjectType3(1, -1) <> swSelSKETCHPOINTS _
    Or swSelMgr.GetSelectedObjectType3(2, -1) <> swSelSKETCHPOINTS Then Exit Sub
   
    Dim swSketch As SldWorks.Sketch: Set swSketch = swmodel.SketchManager.ActiveSketch
   
    If swSketch Is Nothing Then Exit Sub
   
    Set SketchPoints(0) = swSelMgr.GetSelectedObject6(1, -1)
    Set SketchPoints(1) = swSelMgr.GetSelectedObject6(2, -1)
   
    Call swmodel.AddHorizontalDimension2(AvgX, MaxY, 0#)
   
    Call SketchPoints(0).Select(appendflag:=False)
    Call SketchPoints(1).Select(appendflag:=True)
   
    Call swmodel.AddVerticalDimension2(IIf((Left), MinX, MaxX), AvgY, 0#)
   
    swmodel.ClearSelection2 True

End Sub

Private Function TopSkPt() As SldWorks.SketchPoint: Set TopSkPt = IIf(SketchPoints(0).y > SketchPoints(1).y, SketchPoints(0), SketchPoints(1)): End Function
Private Function BtmSkPt() As SldWorks.SketchPoint: Set BtmSkPt = IIf(SketchPoints(0).y < SketchPoints(1).y, SketchPoints(0), SketchPoints(1)): End Function
Private Function MaxX() As Double:  MaxX = IIf(SketchPoints(0).x > SketchPoints(1).x, SketchPoints(0).x, SketchPoints(1).x): End Function
Private Function MinX() As Double:  MinX = IIf(SketchPoints(0).x < SketchPoints(1).x, SketchPoints(0).x, SketchPoints(1).x): End Function
Private Function MaxY() As Double:  MaxY = IIf(SketchPoints(0).y > SketchPoints(1).y, SketchPoints(0).y, SketchPoints(1).y): End Function
Private Function AvgX() As Double:  AvgX = (SketchPoints(0).x + SketchPoints(1).x) / 2: End Function
Private Function AvgY() As Double:  AvgY = (SketchPoints(0).y + SketchPoints(1).y) / 2: End Function
Private Function Left() As Boolean: Left = IIf(TopSkPt.x < BtmSkPt.x, True, False): End Function
See the reply in context

Attachments

No one else had this question

Outcomes